Ab einem bestimmten Datum:

StartDatum = #12/31/2006#
If Now() > StartDatum Then
    ...
End If

Bis zu einem bestimmten Datum:

EndDatum= #12/31/2006#
If Now() < EndDatum Then
    ...
End If

Während eines bestimmten Zeitraumes:

StartDatum = #12/1/2006#
EndDatum = #1/1/2007#
If Now() >= StartDatum And Now() < EndDatum Then
    ...
End If

Via ExcelTips

Wer beim Schreiben von Makros seine selbst erstellten Menüleisten mit kleinen Bildchen oder Symbolen aufpeppen möchte, muss dafür auf die sog. FacIDs zurückgreifen. In der einschlägigen Literatur findet man dazu seitenweise Listen. Das Excel-Addin FaceID Viewer von Doug Glancy erleichtert da die Arbeit sehr und hat auch noch die komfortable Funktion, dass die letzten benutzten IDs in einer separaten Liste abgelegt werden, wo man sie dann einfach wiederfinden kann. Zudem kann man sich die IDs auch thematisch auflisten lassen.

Bei umfangreichen Dokumenten, die man nun weiterverarbeiten möchte, können solche Zeilen und Spalten leicht übersehen werden oder aber das Einblenden und anschließende Löschen zu einer Sisyphusarbeit ausarten. Ein VBA-Makro kann diese Arbeit allerdings leicht übernehmen:

Sub versteckte_loeschen()
    Dim r As Range
    For Each r In Rows(1).Cells
        If r.Width < 1 Then r.EntireColumn.Delete
    Next
    For Each r In Columns(1).Cells
        If r.Height < 1 Then r.EntireRow.Delete
    Next
End Sub

Sub Index()
Dim wSheet As Worksheet
Dim M As Long
M = 1

On Error Resume Next
If Worksheets(1).Name = "Index" Then
MsgBox "Ein Index besteht bereits."
Else
Worksheets.Add Before:=ActiveWorkbook.Worksheets(1)
Worksheets(1).Name = "Index"
End If

With ActiveWorkbook.Worksheets(1)
.Columns(1).ClearContents
.Cells(1, 1) = "INDEX"
.Cells(1, 1).Name = "Index"
End With

For Each wSheet In Worksheets
If wSheet.Name <> ActiveWorkbook.Worksheets(1).Name Then
M = M + 1
With wSheet
.Range("H1").Name = "Start" & wSheet.Index
.Hyperlinks.Add Anchor:=.Range("H1"), Address:="", SubAddress:="Index", TextToDisplay:="Zurück zum Index"
End With
ActiveWorkbook.Worksheets(1).Hyperlinks.Add Anchor:=ActiveWorkbook.Worksheets(1).Cells(M, 1), Address:="", _
SubAddress:="Start" & wSheet.Index, TextToDisplay:=wSheet.Name
End If
Next wSheet
End Sub

Wenn man diesen Index nicht mehr benötigt, kann man ihn mit folgendem Makro wieder löschen:

Sub Index_entfernen()
Dim wSheet As Worksheet

On Error GoTo Fehlermeldung
Application.DisplayAlerts = False 'Unterdrückt Sicherheitsabfrage
Worksheets("Index").Delete
Application.DisplayAlerts = True

For Each wSheet In ActiveWorkbook.Worksheets
wSheet.Activate
Range("H1").Select
Selection.ClearContents
Next wSheet

Exit Sub
Fehlermeldung:
MsgBox ("Es gibt kein Index.")

End Sub

Wenn man in Word viel mit Tabellen arbeitet, bzw. diese bearbeiten muss, kann es manchmal nötig sein alle leeren Zellen zu entfernen. Der Trick dabei ist, dass die leeren Tabellenzellen in Wahrheit überhaupt nicht leer sind, sondern zwei Zeichen beinhalten: Chr(13) und Chr(7). Deswegen muss man dies beim Löschen per VBA berücksichtigen. Ein Makro, das die leeren Zellen der Tabelle löscht, in der sich gerade der Cursor befindet könnte dann so aussehen:

Sub LeereZellen()
Dim oCell As Cell
Dim oRow As Row
On Error GoTo TabellenFM
For Each oRow In Selection.Tables(1).Rows
    For Each oCell In oRow.Cells
        If oCell.Range.Text = Chr(13) & Chr(7) Then
        oCell.Delete ShiftCells:=wdDeleteCellsShiftLeft
        End If
    Next oCell
Next oRow
Exit Sub
TabellenFM: MsgBox ("Fehler: Der Cursor befindet sich nicht in einer Tabelle.")
End Sub

Noch mehr Beispiele gibt es bei Word MVP

Die Angabe ShiftCells:=wdDeleteCellsShiftLeft bedeutet dabei, dass die verbleibenden Zellen der Reihe nach links verschoben werden. Da dies auch die Standardeinstellung ist, kann man auf diese Angabe verzichten. Möchte man jedoch, dass sich die verbleibenden Zellen anders verhalten muss man hier Änderungen vornehmen:

wdDeleteCellsShiftUp entspricht: Zellen nach oben verschieben
wdDeleteCellsEntireRow entspricht: ganze Zeile löschen
wdDeleteCellsEntireColumn entspricht: ganze Spalte löschen

Noch ein kleiner Tipp am Rande. Wenn sich eine Tabelle in einem Worddokument ganz am Anfang (also am oberen Seitenrand befindet) und man über der Tabelle noch etwas einfügen möchte, kann das ganz schön nervenaufreibend sein, denn der Cursor läßt sich nur in die erste Tabellenzeile setzen. Um eine leere Zeile über der Tabelle zu erhalten muss man den Cursor in die oberste Tabellenzeile setzen und dann aus dem Menü „Tabelle” den Punkt „Tabelle teilen” wählen.

Suche: 1), ersetze mit: <FnR RefID=f1>1)</FnR>

Um diesen Vorgang auch für Benutzer, die im Umgang mit Word sehr unerfahren sind komfortabel zu gestalten und um sich das lästige Eintippen des kompletten Tags zu ersparen, habe ich ein Makro erstellt.

Die Userform beinhaltet folgendes:

Private Sub Abbrechen_Click()
    Unload Fussnoten
End Sub

Private Sub Ersetze_Change()
End Sub

Private Sub OK_Click()
    FussnotenTags
End Sub

Private Sub Suche_Change()
End Sub

Folgendes Makro ruft die Userform auf:

Sub FussnotenAbfrage()
    Fussnoten.Show vbModeless
End Sub

Dieses Makro verarbeitet die eingegebenen Angaben:

Sub FussnotenTags()

strSuche = Fussnoten.Suche.Text
strErsetze = Fussnoten.Ersetze.Text

    Selection.Find.ClearFormatting
    Selection.Find.Replacement.ClearFormatting
    With Selection.Find
        .Text = strSuche & "^t"
        .Replacement.Text = "<FnR RefID=" & strErsetze & ">" & strSuche & "</FnR>"
        .Forward = True
        .Wrap = wdFindContinue
    End With
    Selection.Find.Execute Replace:=wdReplaceAll
Unload Fussnoten
End Sub

Kritische Stellen (je nach Dokument) sind jedoch leider noch vorhanden:

Da man bei einer Suche nach Zahlen oder Zeichen, aus denen eine klassische Fußnote ja besteht, nicht die Option “ganzes Wort” aktivieren kann, bzw. die Einstellung .MatchWholeWord = True keine Auswirkung hat, muss zuerst nach zweistelligen Fußnoten gesucht werden und dann nach einstelligen.

Außerdem habe ich die Suche eingeschränkt, so dass nach dem gesuchten Zeichen ein Tabstopp folgen muss. Damit verhindere ich, dass das Makro die Fußnote „11)” noch einmal findet, wenn danach nach der Fußnote „1)” gesucht wird. Diese Abgrenzung könnte je nach Dokument natürlich auch ein Leerschritt, Punkt o. ä. sein.

Sub Tabellenblaetter()
Dim TabellenBlatt As Byte
Dim FreieZeile As Integer

Worksheets(1).Activate

For TabellenBlatt = 2 To Sheets.Count

FreieZeile = Worksheets(1).UsedRange.SpecialCells(xlCellTypeLastCell).Row
Worksheets(TabellenBlatt).UsedRange.Copy _
Destination:=Worksheets(1).Cells(FreieZeile + 1, 1)

Next TabellenBlatt

End Sub

Dazu setzt man die Zeile StartUndoSaver einfach an den Beginn eines Makros und die Zeile EndUndoSaver an das Ende, so dass man folgendes erhält:

Sub Irgendwas
StartUndoSaver
Hier kommt der Code.
EndUndoSaver
End Sub

Zusätlich muss man noch folgende Makros haben, die man am Besten in einem eigenen Modul einfügt:

Option Explicit

Sub StartUndoSaver()
On Error Resume Next
ActiveDocument.Bookmarks.Add "_InMacro_"
On Error GoTo 0
End Sub

Sub EndUndoSaver()
On Error Resume Next
ActiveDocument.Bookmarks("_InMacro_").Delete
On Error GoTo 0
End Sub

Sub EditUndo() ' Catches Ctrl-Z
If ActiveDocument.Undo = False Then Exit Sub
While BookMarkExists("_InMacro_")
If ActiveDocument.Undo = False Then Exit Sub
Wend
End Sub

Sub EditRedo() ' Catches Ctrl-Y
If ActiveDocument.Redo = False Then Exit Sub
While BookMarkExists("_InMacro_")
If ActiveDocument.Redo = False Then Exit Sub
Wend
End Sub

Private Function BookMarkExists(Name As String) As Boolean
On Error Resume Next
BookMarkExists = Len(ActiveDocument.Bookmarks(Name).Name) > -1
On Error GoTo 0
End Function

Nach dem Ausführen eines Makros, das mit dem Code (StartUndoSaver und EndUndoSaver) umschlossen wurde, kann man jetzt mit Strg+Z das komplette Makro rückgängig machen und mit Strg+Y wieder herstellen.

In der Dropdownliste erkennt man das umschlossene Makro an den „Textmarken”.

So und jetzt bin ich noch auf der Suche nach einer ähnlichen Lösung für Excel-Makros. Eine Möglichkeit habe ich dazu bei J-Walk.com gefunden, werde aber nicht recht schlau daraus.

Außerdem kann es zu Problemen kommen, wenn man diesen Text in eine andere Anwendung exportieren oder kopieren möchte, wenn unterwegs die Formatierung verloren geht.

Das folgende Makro wandelt alle Absätze deren Text die Formatierung Großbuchstaben enthält in „richtige” Großbuchstaben um:

Sub VersalKonvertieren
Dim oPar As Paragraph
     For Each oPar In ActiveDocument.Paragraphs
        If (Len(oPar.Range.Text) > 1) And _
        (oPar.Range.Font.AllCaps = True) Then
        oPar.Range.Case = wdUpperCase
        End If
     Next oPar
End Sub

Handelt es sich um Text, der nicht als Großbuchstabe sondern als Kapitälchen formatiert wurde, muss man „AllCaps” mit „SmallCaps” ersetzen.

Franz jagt im komplett verwahrlosten Taxi quer durch Bayern.

Füllt man die Klammer (wie o. a.) nicht aus, erscheinen 3 Absatze mit jeweils 5 Sätzen dieses Textes. Man kann aber auch die Anzahl der Absätze und der darin enthaltenen Sätze bestimmen, wobei die erste Zahl die Anzahl der Absätze und die zweite Zahl die Anzahl der in einem Absatz vorkommenden Sätze bestimmt: =rand(1.2) ergibt also einen Absatz mit zwei Sätzen.

Eine umfangreiche Sammlung von Blindtexten findet man bei Newmediadesigner. Mein persönlicher Favorit:

Blind von Geburt an

Ich bin Blindtext. Von Geburt an. Es hat lange gedauert, bis ich begriffen habe, was es bedeutet, ein blinder Text zu sein: Man macht keinen Sinn. Man wirkt hier und da aus dem Zusammenhang gerissen. Oft wird man gar nicht erst gelesen. Aber bin ich deshalb ein schlechter Text? Ich weiss, dass ich nie die Chance haben werde, im Stern zu erscheinen. Aber bin ich darum weniger wichtig? Ich bin blind! Aber ich bin gerne Text. Und sollten Sie mich jetzt tatsächlich zu Ende lesen, dann habe ich etwas geschafft, was den meisten “normalen” Texten nicht gelingt.

Hier zwei Beispiele:

Sub Textboxen()
'Text in Textboxen wird grün

Dim Form As Shape

On Error Resume Next

For Each Form In ActiveDocument.Shapes
If Form.Type = msoTextBox Then
Form.TextFrame.TextRange.Font.Color = wdColorGreen
End If
Next

End Sub

Sub Linienloeschen()

'Linien werden gelöscht

Dim Form As Shape
For Each Form In ActiveDocument.Shapes
If Form.Type = msoLine Then
Form.Delete
End If
Next

End Sub

Bei René Probst gibt es eine Auflistung sämtlicher Shapes.

1. Überflüssige Leerzeilen, -zeichen u. ä. löschen
2. Sonderzeichen maskieren
3. Internet- und E-Mail-Adressen „umsetzen”
4. Absätze mit Tags umschließen
5. Ungeordnete und Geordnete Listen kennzeichen

Um all diese Schritte automatisch vornehmen zu können, habe ich ein Makro zusammengestellt, das dies alles erledigt.

gezippte .txt-Datei
Text-Datei herunterladen und den Text in ein Modul kopieren.

gezipptes Modul
Die Datei herunterladen und dann im MS Script-Editor importieren.

Zum Anwenden das Makro „Struktur” aufrufen. Für die Listen einen Bereich markieren und dann das entsprechende Makro aufrufen.

Möchte man in einem Word-Dokument nicht nur einfache Buchstaben, sondern evtl. mehrere Absatzmarken finden und auch ersetzen ist der einfachste Weg natürlich über Strg+H bzw. Bearbeiten –> Ersetzen. Dort muss man dann das Feld „Erweitern” anklicken. Man erhält dann folgendes Bild:

Hier setzt man jetzt den Cursor in das Suchen-Feld und klickt anschließend auf „Sonstiges”. Man erhält eine Auswahlliste auf der man (für das jetzige Beispiel) auf „Absatzmarke” klickt. Im Suchenfeld wurde jetzt automatisch ^p eingefügt. Möchte man jedoch mehrere aufeinander folgende Absatzmarken suchen ist es sehr umständlich (und vor allen Dingen auch unnötig nun mehrere ^ps hintereinander einzugeben, insbesondere dann wenn im Dokument die Anzahl der aufeinander folgenden Absatzmarken variiert, d. h. an einer Stelle sind 3 Absatzmarken an einer anderen Stelle evtl. 17 Absatzmarken hintereinander.

Um all diese Fälle mit einem Suchgang, bzw. mit einer Suchprozedur im VBA-Code abzufangen muss man Platzhalter verwenden. Wenn man also ein Häkchen bei „Platzhalterzeichen verwenden” macht und dann erneut auf „Sonstiges” klickt erscheint eine völlig andere Liste als vorher – eben die Platzhalter. In diesem Beispiel würde man also den Platzhalter „Anzahl Vorkommen” wählen. Es erscheint { ; } im Suchen-Feld. Hier kann man nun zwei Zahlen im Sinne „von …. bis …” eingeben, also z. B. {2;100}.

Achtung: Hat man hier z. B. nachgeschaut, um diesen Code in eine VBA-Prozedur zu übernehmen muss man darauf achten, dass man ein Semikolon nimmt und nicht wie in der Übersicht angezeigt ein Komma!

Man kann jetzt meinen Word würde jetzt alle Stellen im Text finden an denen zwei bis hundert Absatzmarken aufeinander folgen, aber man erhält diese Fehlermeldung:

Möchte man nämlich mit Hilfe von Platzhaltern suchen muss man diese Option vorher aktivieren und hat man dies getan, fällt einem schnell auf, dass die Abatzmarke (im Gegensatz zum z. B. Tabstopp) gar nicht als Möglichkeit angeführt wird. Um Word hier zu überlisten muss man also auf den ASCII-Code zurückgreifen, der ist für die Absatzmarke „13”. Eingeben muss man ihn allerdings sowohl im Suchfeld also auch im VBA-Code so: ^013. Die Suche nach mehreren Absatzmarken sieht also so aus:

^013{2;100}

Beim Ersetzen kann man allerdings wieder auf das ^p zurückgreifen.

Den entsprechenden Code findet man übrigens innerhalb von Word, wenn man auf Einfügen –> Symbol klickt.

Innerhalb von Word kann man den Ascii-Code auch mit gedrückter Alt-Taste und der entsprechenden dreistelligen Nummer auf dem Zahlenblock eingeben, das Enterzeichen also als Alt+013.

Im Internet findet man sämtliche Unicode-Tabellen hier und eine übersichtliche ASCII-Code-Tabelle hier.

Kürzer geht es, wenn man sich ein Makro erstellt, das nur die Suchroutine enthält und dann ein Extra-Makro, innerhalb dessen dann die Suche-Ersetze-Begriffe „aufgelistet” sind, die dann auf das Suche-Ersetze-Makro zugreifen. Noch übersichtlicher wird das ganze, wenn man das Suche-Ersetze-Makro in ein eigenes Modul einfügt.

Beispiel für das Suche-Ersetze-Makro:

Sub SuErNo(FindText As String, ReplaceText As String)
'SuErNo = SucheErsetzeNormal

With Selection.Find
.ClearFormatting
.Replacement.ClearFormatting löscht alles was in der Suche-Ersetze-Maske vorher war

.Text = FindText
.Replacement.Text = ReplaceText

.Forward = True ‘Suchrichtung: vom Anfang
.Wrap = wdFindContinue ‘ganzes Dokument ohne Nachfrage
.Format = False ‘Formatierung nicht beachten
.MatchCase = True ‘Groß-/Kleinschreibung beachten
.MatchWholeWord = True
.MatchWildcards = False ‘Platzhalter nicht beachten

.Execute Replace:=wdReplaceAll
End With
End Sub

Und so greift man auf dieses Makro zu:

Call SuErNo("i.H.v.", "i. H. v.")
Call SuErNo("i.V.m.", "i. V. m.")
Call SuErNo("p.a.", "p. a.")
Call SuErNo("u.a.", "u. a.")